/* improvements in the -list- command */

use http://www.ats.ucla.edu/stat/stata/notes/hsb2

list in 1/20
list in 1/20, sep(10)
list in 1/20, sep(10) header(10)
list in 1/20, nolabel
list read write math science if schtyp==2 & ses==2, mean(read write math science)

/* enhanced -recode- */

recode write 0/60=0 60/100=1 else=. , generate(hiwrite)

recode read math science socst (0/60=0) (60/100=1) (else=.) , prefix(hi)

/* improvements in the -tabulate- command */

tabulate prog ses, exp all
tabulate prog ses, exp cchi2 chi2

tabulate ses
describe ses
numlabel sl, add
tabulate ses

/* new command -manova- */

manova write read math = prog female prog*female

/* -manovatest */

manova write =  prog

manovatest, showorder
mat c = (0,-1,2,-1)
manovatest, test(c)

manova read write math = prog

mat d = (0,1,0)
manovatest prog, ytransform(d)

mat d = (1,1,0)
manovatest prog, ytransform(d)

/* improved syntax for -test- */

regress math read write socst

test read=write
test read=write=socst

/* improvements in managing -estimate- results */

regress write read female
est store m1
regress write read female math
est store m2
regress write read female math science
est store m3

est table m1 m2 m3, stats(r2 aic bic)

/* new command -permute- */

     /* begin ado */
     program define tpermute
     version 8
        quietly ttest `2' , by(`1')         
     end
     /* end ado */

permute female "tpermute female science" t=r(t), reps(500) 
ttest science, by(schtyp)

/* new command -suest- for seemingly unrelated estimation */

regress write read if ~female
est store m1
regress write read if female
est store m2

suest m1 m2

test [m1_mean=m2_mean], cons

/* new data checking commands */

use http://www.gseis.ucla.edu/courses/data/clean

isid id

duplicates report id
duplicates list id

use http://www.ats.ucla.edu/stat/stata/notes2/hs0

codebook, problems

/* new graphics system */

use http://www.ats.ucla.edu/stat/stata/notes/hsb2

histbox write, normal mean bin(7)

graph7 write, hist normal bin(7)

hist write, normal start(30) width(5)

hist prog, discrete xlab(1 2 3)

twoway scatter math write, jitter(2) || lfit math write
twoway scatter math write, jitter(2) || lfitci math write
twoway scatter math write, jitter(2) || lfit math write || qfit math write

scatter write read, by(female, total row(1)) jitter(2)

graph box write, over(female) over(prog)

#delimit ;
twoway scatter math write, 
	     yscale(alt) xscale(alt) 
	     xlabel(, grid gmax)              saving(yx);
     
twoway histogram math, fraction
	     xscale(alt reverse) horiz        saving(hy);
     
twoway histogram write, fraction
	     yscale(alt reverse)
	     ylabel(,nogrid)
	     xlabel(,grid gmax)               saving(hx);

graph combine hy.gph yx.gph hx.gph, hole(3) imargin(0 0 0 0);
#delimit cr

sysuse uslifeexp, clear

twoway line le_wm year || line le_bm year

use http://www.ats.ucla.edu/stat/data/crime, clear

twoway scatter crime poverty, msym(D)
twoway scatter crime poverty, msym(i) mlab(state)
twoway scatter crime poverty, msym(D) mlab(state)

#delimit ;
twoway scatter crime poverty, msym(O) mlab(state) 
  || lfit crime poverty 
  || lfit crime poverty if sid~=51;
#delimit cr


/* new -cluster- algorithms */

clear
input lep read math lang str3 district
.38 626.5 601.3 605.3 lau
.18 654.0 647.1 641.8 ccu
.07 677.2 676.5 670.5 bhu
.09 639.9 640.3 636.0 ing
.19 614.7 617.3 606.2 com
.12 670.2 666.0 659.3 smm
.20 651.1 645.2 643.4 bur
.41 645.4 645.8 644.8 gln
.07 683.5 682.9 674.3 pvu
.39 648.6 647.8 643.1 sgu
.21 650.4 650.8 643.9 abc
.24 637.0 636.9 626.5 pas
.09 641.1 628.8 629.4 lan
.12 638.0 627.7 628.6 plm
.11 661.4 659.0 651.8 tor
.22 646.4 646.2 647.0 dow
.33 634.1 632.0 627.8 lbu
end

cluster wards lep read math lang, name(wclu)

cluster tree wclu, label(district) vertl

list