Stat Computing > SPSS > Textbook Examples > Regression with Graphics, by Hamilton				Help the Stat Consulting Group by giving a gift
Loading

SPSS Textbook Examples
Regression with Graphics by Lawrence Hamilton
Chapter 7: Logit regression

Limitations of linear regression

Page 218 Figure 7.1  Linear regression of a dichotomous Y variable (0 = open schools, 1 = close schools) on a measurement X variable (years lived in town).

GET FILE 'd:\apps\rwgdata\toxic.sav'.

formats lived (f2.0) close (f2.1).
GGRAPH
  /GRAPHDATASET NAME="graphdataset" VARIABLES=lived close
  /GRAPHSPEC SOURCE=INLINE.
BEGIN GPL
SOURCE: s=userSource(id("graphdataset"))
DATA: lived=col(source(s), name("lived"))
DATA: close=col(source(s), name("close"))
GUIDE: text.title( label( "Figure 7.1" ) )
GUIDE: form.line(position(*, 1), shape(shape.half_dash))
GUIDE: form.line(position(*, 0), shape(shape.half_dash))
GUIDE: axis(dim(1), label("Years Lived in Town"), delta(10))
GUIDE: axis(dim(2), label("Favor Closing Schools"), delta(.2))
SCALE: linear(dim(1), min(0), max(80))
SCALE: linear(dim(2), min(-.2), max(1))
ELEMENT: point(position(lived*close))
ELEMENT: line(position(smooth.linear(lived*close)), shape(shape.dash))
END GPL.

Page 219 Figure 7.2  Boxplots and oneway scatterplots of years lived in town, for respondents favoring closed and open schools.

compute const=.01.
execute.

EXAMINE  VARIABLES=lived BY close
 /PLOT=BOXPLOT
 /STATISTICS=NONE.

Page 222 Figure 7.4  Logit regression of school-closing opinion on years lived in town, also showing linear regression line.

GGRAPH
  /GRAPHDATASET NAME="graphdataset" VARIABLES=lived close
  /GRAPHSPEC SOURCE=INLINE.
BEGIN GPL
SOURCE: s=userSource(id("graphdataset"))
DATA: lived=col(source(s), name("lived"))
DATA: close=col(source(s), name("close"))
GUIDE: text.title( label( "Figure 7.4" ) )
GUIDE: form.line(position(*, 1), shape(shape.half_dash))
GUIDE: form.line(position(*, 0), shape(shape.half_dash))
GUIDE: axis(dim(1), label("Years Lived in Town"), delta(10))
GUIDE: axis(dim(2), label("Favor Closing Schools"), delta(.2))
SCALE: linear(dim(1), min(0), max(80))
SCALE: linear(dim(2), min(-.2), max(1))
ELEMENT: point(position(lived*close))
ELEMENT: line(position(smooth.linear(lived*close)), shape(shape.dash))
ELEMENT: line(position(smooth.quadratic(lived*close)))
END GPL.

Page 224 Table 7.1  Logit regression of school-closing opinion on years lived in town.

LOGISTIC REGRESSION VAR=close
  /METHOD=ENTER lived.

Page 226 Table 7.2  Logit regression of school-closing opinion on years lived in town, education, contamination, and HSC meetings.

LOGISTIC REGRESSION VAR=close
  /METHOD=ENTER lived educ contam hsc.

Page 227 Table 7.3  Logit regression of school-closing opinion on seven background variables.

LOGISTIC REGRESSION VAR=close
  /METHOD=ENTER lived educ contam hsc female kids nodad
  /PRINT=ITER(1) SUMMARY.

Page 228 Table 7.4  Reduced model with male/nonparent interaction term.

LOGISTIC REGRESSION VAR=close
  /METHOD=ENTER lived educ contam hsc nodad.

Page 232 Figure 7.5  Conditional effects of years lived in town, at proclosing (top), average, and anticlosing levels of other X variables.

LOGISTIC REGRESSION VAR=close
  /METHOD=ENTER lived educ contam hsc nodad.

SORT CASES BY
  lived (A).

compute lhat1 = 3.17-.04*lived.
compute phat1 = 1/(1+exp(-lhat1)).
compute lhat2 = .387-.04*(lived).
compute phat2 = 1/(1+exp(-lhat2)).
compute lhat3 = -2.14-.04*(lived).
compute phat3 = 1/(1+exp(-lhat3)).
execute.

formats lived (f2.0) phat1 phat2 phat3 (f2.1).
GGRAPH
  /GRAPHDATASET NAME="graphdataset" VARIABLES=lived phat1 phat2 phat3 
  /GRAPHSPEC SOURCE=INLINE.
BEGIN GPL
SOURCE: s=userSource(id("graphdataset"))
DATA: lived=col(source(s), name("lived"))
DATA: phat1=col(source(s), name("phat1"))
DATA: phat2=col(source(s), name("phat2"))
DATA: phat3=col(source(s), name("phat3"))
GUIDE: text.title( label( "Figure 7.5" ) )
GUIDE: axis(dim(1), label("Years Lived in Town"), delta(10))
GUIDE: axis(dim(2), label("Probability of Favoring School Closing"), delta(.2))
SCALE: linear(dim(1), min(0), max(80))
SCALE: linear(dim(2), min(0), max(1))
ELEMENT: line(position(smooth.spline(lived*phat1)), shape(shape.dash))
ELEMENT: line(position(smooth.spline(lived*phat2)))
ELEMENT: line(position(smooth.spline(lived*phat3)), shape(shape.half_dash))
END GPL.

Page 232 Figure 7.6  Conditional effects of contamination, at proclosing, average, and anticlosing levels of other X variables.

SORT CASES BY contam (A).
compute lhat4 = 3.22+1.3*(contam).
compute phat4 = 1/(1+exp(-lhat4)).
compute lhat5 = -.7681+1.3*(contam).
compute phat5 = 1/(1+exp(-lhat5)).
compute lhat6 = -6.79+1.3*(contam).
compute phat6 = 1/(1+exp(-lhat6)).
execute.

SORT CASES BY
  contam (A).

value labels contam 0 "Not contaminated" 1 "Contaminated".
formats contam (f1.0) phat4 phat5 phat6 (f2.1).
GGRAPH
  /GRAPHDATASET NAME="graphdataset" VARIABLES=contam phat4 phat5 phat6 
  /GRAPHSPEC SOURCE=INLINE.
BEGIN GPL
SOURCE: s=userSource(id("graphdataset"))
DATA: contam=col(source(s), name("contam"), unit.category() )
DATA: phat4=col(source(s), name("phat4"))
DATA: phat5=col(source(s), name("phat5"))
DATA: phat6=col(source(s), name("phat6"))
GUIDE: text.title( label( "Figure 7.6" ) )
GUIDE: axis(dim(1), label(" "))
GUIDE: axis(dim(2), label("Probability of Favoring School Closing"), delta(.2))
SCALE: linear(dim(2), min(-.2), max(1))
ELEMENT: line(position(smooth.spline(contam*phat4)), shape(shape.dash))
ELEMENT: line(position(smooth.spline(contam*phat5)))
ELEMENT: line(position(smooth.spline(contam*phat6)), shape(shape.half_dash))
END GPL.

Page 239 Figure 7.7  Poorness-of-fit statistic delta-chi-square(P) versus predicted probability of favoring closed schools; X patterns 131 and 3 are poorly fit (high delta-chi-square(P) values).

LOGISTIC REGRESSION VAR=close
  /METHOD=ENTER lived educ contam hsc nodad
  /SAVE PRED COOK LEVER ZRESID DEV.

compute deltap=(zre_1)**2/(1-lev_1).
execute.

formats pre_1 (f2.1) deltap (f2.0).
GGRAPH
  /GRAPHDATASET NAME="graphdataset" VARIABLES=pre_1 deltap
  /GRAPHSPEC SOURCE=INLINE.
BEGIN GPL
SOURCE: s=userSource(id("graphdataset"))
DATA: deltap=col(source(s), name("deltap"))
DATA: pre_1=col(source(s), name("pre_1"))
GUIDE: text.title( label( "Figure 7.7" ) )
GUIDE: axis(dim(1), label("P-hat"), delta(.2))
GUIDE: axis(dim(2), label("Delta P"), delta(5))
SCALE: linear(dim(1), min(0), max(1))
SCALE: linear(dim(2), min(0), max(30))
ELEMENT: point(position(pre_1*deltap))
END GPL.

Page 240 Figure 7.8  Poorness-of-fit statistic delta-chi-square(D) versus predicted probability of favoring closed schools; X patterns 131, 3, 27, 62, 115 are poorly fit (high delta-chi-square(D) values).

compute deltad=(dev_1)**2/(1-lev_1).
execute.

formats deltad (f2.0).
GGRAPH
  /GRAPHDATASET NAME="graphdataset" VARIABLES=pre_1 deltad
  /GRAPHSPEC SOURCE=INLINE.
BEGIN GPL
SOURCE: s=userSource(id("graphdataset"))
DATA: deltad=col(source(s), name("deltad"))
DATA: pre_1=col(source(s), name("pre_1"))
GUIDE: text.title( label( "Figure 7.8" ) )
GUIDE: axis(dim(1), label("P-hat"), delta(.2))
GUIDE: axis(dim(2), label("Delta D"), delta(1))
SCALE: linear(dim(1), min(0), max(1))
SCALE: linear(dim(2), min(0), max(7))
ELEMENT: point(position(pre_1*deltad))
END GPL.

Page 241 Figure 7.9  Influence statistic delta-B versus predicted probability of favoring closed schools; patterns 131, 3, 115, 44, and 94 are most influential (high delta-B values).

NOTE:  Delta-B is the Cook's D statistic.

formats coo_1 (f2.1).
GGRAPH
  /GRAPHDATASET NAME="graphdataset" VARIABLES=pre_1 coo_1
  /GRAPHSPEC SOURCE=INLINE.
BEGIN GPL
SOURCE: s=userSource(id("graphdataset"))
DATA: coo_1=col(source(s), name("coo_1"))
DATA: pre_1=col(source(s), name("pre_1"))
GUIDE: text.title( label( "Figure 7.9" ) )
GUIDE: axis(dim(1), label("P-hat"), delta(.2))
GUIDE: axis(dim(2), label("Delta B"), delta(.1))
SCALE: linear(dim(1), min(0), max(1))
SCALE: linear(dim(2), min(0), max(.7))
ELEMENT: point(position(pre_1*coo_1))
END GPL.

Page 242 Figure 7.10  Delta-chi-square(D) versus P-hat with symbols proportional to delta-B; large, high circles indicate influential, poorly fit X patterns.

GGRAPH
  /GRAPHDATASET NAME="graphdataset" VARIABLES=pre_1 deltad coo_1
  /GRAPHSPEC SOURCE=INLINE.
BEGIN GPL
SOURCE: s=userSource(id("graphdataset"))
DATA: deltad=col(source(s), name("deltad"))
DATA: pre_1=col(source(s), name("pre_1"))
DATA: coo_1=col(source(s), name("coo_1"))
GUIDE: text.title( label( "Figure 7.10" ) )
GUIDE: axis(dim(1), label("P-hat"), delta(.2))
GUIDE: axis(dim(2), label("Delta D"), delta(1))
SCALE: linear(dim(1), min(0), max(1))
SCALE: linear(dim(2), min(0), max(7))
ELEMENT: point(position(pre_1*deltad), size(coo_1))
END GPL.

UCLA Researchers are invited to our Statistical Consulting Services
We recommend others to our list of Other Resources for Statistical Computing Help
These pages are Copyrighted (c) by UCLA Academic Technology Services