Stat Computing > SAS > Textbook Examples > Survival Analysis, by Klein and Moeschberger

SAS Textbook Examples
Survival Analysis by John P. Klein and Melvin L. Moeschberger
Chapter 10: Additive Hazards Regression Model

The material in this chapter is based on the M215 (Fall 2001) Final Project Report by Dong Ding, Weihua Huang, Luohua Jiang, Liyuan Xiong and Kefei Zhou. We thank them for permission to adapt and distribute this page via our web site. This chapter is all done using the SAS macro program for the additive hazard model provided from the author's website.

Section 12.2: Least-Squares Estimation for the Nonparametric, Additive Hazard Model

Example 10.1 using the breast cancer data set described in Section 1.5. We have created a data step for it and you can download it from here.

%include 'c:\sasmacros\additive.sas';

proc sort data = sec1_5;
 by time; 
run;
data bcnew; 
  set sec1_5; 
  positive = (group=2);
  drop group; 
run;
proc iml;

  option={y, n, y, n, n};
  contr={1 -1}; 
  effects={'positive'};
  timeunit={'month'};

%additive (bcnew,0.05, timeunit, effects,  option, contr, betab, testb);

quit;

title "Figure 10.1";
axis1 label=(j=c 'Months') order=(0 to 100 by 20) minor = none;
axis2 label=(a=90 j=c 'Estimated Baseline Cumulative Hazard Rate for Immunoperoxidase Negative Patients')
      order=(0.0 to 1.0 by 0.2) minor = none;
symbol1 interpol=stepjr c=black l=1 value=none;
symbol2 interpol=stepjr c=blue l=3 value=none;
symbol3 interpol=stepjr c=red l=3 value=none;

proc gplot data=betab;
  plot col2*col1 col6*col1 col8*col1/overlay haxis=axis1 vaxis=axis2;
run;
quit;

title "Figure 10.2";
axis1 label=(j=c 'Months') order=(0 to 100 by 20) minor=none;
axis2 label=(a=90 j=c 'Estimated Cumulative Excess Risk for Immunoperosidase Positive Patients')
      order=(-0.5 to 2.0 by 0.5) minor=none;
 
proc gplot data=betab;
  plot col3*col1 col7*col1 col9*col1/overlay haxis=axis1 vaxis=axis2;
run;
quit;

Example 10.2 on page 311 using data set larynx described in section 1.8.

data larynx1;
  length time death z1-z3 age 8.;
  set larynx; 
  z1=(stage=2); 
  z2=(stage=3); 
  z3=(stage=4); 
  age=age-64.11;
  keep time death z1 z2 z3 age; 
run;
proc sort data = larynx1; 
   by time; 
run;

proc iml;

option={ n, y, y, n, y}; 
contrast={0 1 -1 0 0, 0 0 1 -1 0};
effects={'stage II', 'stage III' ,'stage IV', 'age'};
timeunit={'Years'};

%additive (larynx1, 0.05, timeunit, effects,  option, contrast, beta, test);

quit;

title "Figure 10.3";
axis1 label=(j=c 'Years') minor=none;
axis2 label=(a=90 j=c 'Estimated Baseline Cumulative Hazard Rate for Stage I Patients')
      minor = none;

proc gplot data=beta;
plot col2*col1 col12*col1 col17*col1/overlay haxis=axis1 vaxis=axis2;
run;
quit;

title "Figure 10.4";
axis1 label=(j=c 'Years') minor=none;
axis2 label=(a=90 j=c 'Estimated Cumulative Excess Risk of Stage II Patients')
      order=(-0.4 to 0.6 by 0.2) minor = none;

proc gplot data=beta;
plot col3*col1 col13*col1 col18*col1/overlay haxis=axis1 vaxis=axis2;
run;
quit;

title "Figure 10.5";
axis1 label=(j=c 'Years') minor=none;
axis2 label=(a=90 j=c 'Estimated Cumulative Excess Risk of Stage III Patients')
      order=(-0.2 to 0.8 by 0.2) minor=none;

proc gplot data=beta;
plot col4*col1 col14*col1 col19*col1/overlay haxis=axis1 vaxis=axis2;
run;
quit;

title "Figure 10.6";
axis1 label=(j=c 'Years') minor = none;
axis2 label=(a=90 j=c 'Estimated Cumulative Excess Risk of Stage IV Patients')
      order=(-0.5 to 3.5 by 0.5) minor = none;

proc gplot data=beta;
  plot col5*col1 col15*col1 col20*col1/overlay haxis=axis1 vaxis=axis2;
run;
quit;

title "Figure 10.7";
axis1 label=(j=c 'Years') minor = none;
axis2 label=(a=90 j=c 'Estimated Cumulative Excess Risk Due to Age')
      order=(-0.02 to 0.04 by 0.02) minor = none;

proc gplot data=beta;
plot col6*col1 col16*col1 col21*col1/overlay haxis=axis1 vaxis=axis2;
run;
quit;

Section 10.3: Testing in the Nonparametric Additive Hazard Model

Table in the middle of page 323 of Example 10.2 (continued).

options nocenter;
proc iml;

option={ n, y, y, n, y}; 
contrast={0 1 -1 0 0, 0 0 1 -1 0};
effects={'stage II', 'stage III' ,'stage IV', 'age'};
timeunit={'Years'};

%additive (larynxf, 0.05, timeunit, effects,  option, contrast, beta, test);

quit;

    Additive Hazards Model

No missing data: all observations were used in analysis.

       90 observations used.

Estimates are restricted to the time interval 0 to 4.30

               Global Test

Chi-Square d.f p-value

   10.9613   4  0.0270

           Analysis of Variance

Effect    Chi-Square d.f p-value

stage II      0.1456   1  0.7027
stage III     3.0062   1  0.0829
stage IV      8.4655   1  0.0036
age           0.2333   1  0.6291

        Test of Linear Combinations

Contrast Matrix         0         1        -1         0         0
                        0         0         1        -1         0

Chi-Square d.f p-value

    6.8131   2  0.0332

UCLA Researchers are invited to our Statistical Consulting Services
We recommend others to our list of Other Resources for Statistical Computing Help
These pages are Copyrighted (c) by UCLA Academic Technology Services