title:
  Data from page 166 in EQS program.
  Input based on Appendix 6.3 page 166, but is only
    for group 4 (the true longitudinal group).
  Figure 6.1 page 77, group 4 only.
  Output. 

    Table 6.4 (cohort sequential), page 81.
    NOTE. Correlation is standardized value of
      int with slope.

    Also Table 6.5 (cohort sequetial), computed
    based on intercept and slope values, e.g.
      ***** NOT DONE YET ***
      age 12: .310 + 0*.384 = .31
      age 13: .310 + 1*.384 = .694
      age 14: .310 + 2*.384 = 1.078
      age 15: .310 + 3*.384 = 1.462
      age 16: .310 + 4*.384 = 1.846
  Streamlined specification

data:  
  file = ch6cs.dat;
  format = free;
  type = means covariance;
  ngroups = 3;
  nobservations = 248 250 231;
variable:  
  names = y1 y2 y3; 
  usevar =  y1-y3;
analysis:  
  type = general mgroup meanstructure;          
  iterations = 100;
model:
  ! this is the overall model
  int by y1@1 y2@1 y3@1;  ! Note 1
  slp by y1@0 y2@1 y3@1;  ! overidden for each group
  [y1-y3@0];              ! Note 1
  [int]         (mint);   ! Note 1, also see Note 2
  [slp]         (mslp);   ! Note 1, also see Note 2
  int with slp  (intslp); ! Note 1
  int           (vint);   ! Note 1
  slp           (vslp);   ! Note 1
  y1            (e14);    ! overidden for each group
  y2            (e15);    ! overidden for each group
  y3            (e16);    ! overidden for each group
model g1:
  ! this is the model for group 1
  slp by y1@0 ;      ! age 12 @ 0
  slp by y2@1 ;      ! age 13 @ 1
  slp by y3 (age14); ! age 14 free, but constrained
  [int]         (mint);   ! Note 2
  [slp]         (mslp);   ! Note 2
  y1            (e12);
  y2            (e13);
  y3            (e14);
model g2:
  ! this is the model for group 2
  slp by y1@1;       ! age 13 @ 1
  slp by y2 (age14); ! age 14 free but constrained
  slp by y3 (age15); ! age 15 free but constrained
  y1            (e13);
  y2            (e14);
  y3            (e15);
model g3:
  ! this is the model for group 3
  slp by y1 (age14); ! age 14 free but constrained
  slp by y2 (age15); ! age 15 free but constrained
  slp by y3 (age16); ! age 16 free but constrained
  y1            (e14);
  y2            (e15);
  y3            (e16);
output: 
  standardized tech1;

! Note 1
!   Note that these constraints are given just in
!   the overall model, but are implied across
!   all groups (except see Note 2).
! Note 2
!   Be default, Mplus holds the means of these factors to be 0 
!   for the first group.  To override this, we include these
!   factor means for group 1.