title:
  Data from page 162 in EQS program.
  Input based on Appendix 6.1 page 162.
  Figure 6.1 page 77, first 3 groups only
  Output. 
    Table 6.2 (cohort sequential columns), page 79.
    NOTE. Correlation is standardized value of
      int with slope.
    Also see text at top of page 79.

    Also Table 6.3 (cohort sequential column), computed
    based on intercept and slope values, e.g.
      age 12: .310 + 0*.384 = .31
      age 13: .310 + 1*.384 = .694
      age 14: .310 + 2*.384 = 1.078
      age 15: .310 + 3*.384 = 1.462
      age 16: .310 + 4*.384 = 1.846
data:  
  file = ch6cs.dat;
  format = free;
  type = means covariance;
  ngroups = 3;
  nobservations = 248 250 231;
variable:  
  names = y1 y2 y3; 
analysis:  
  type = general mgroup meanstructure;          
model:
  ! this is the overall model
  int by y1@1 y2@1 y3@1; 
  slp by y1@0 y2@1 y3@1;  ! overidden for each group
  [y1-y3@0];              ! Note 1
  [int]         (mint);   ! Note 1
  [slp]         (mslp);   ! Note 1
  int with slp  (intslp); ! Note 1
  int           (vint);   ! Note 1
  slp           (vslp);   ! Note 1
  y1            (e14);    ! overidden for each group
  y2            (e15);    ! overidden for each group
  y3            (e16);    ! overidden for each group
model g1:
  ! this is the model for group 1
  int by y1@1 y2@1 y3@1; 
  slp by y1@0 ; ! age 12
  slp by y2@1 ; ! age 13
  slp by y3@2 ; ! age 14
  [y1-y3@0];              ! Note 1
  [int]         (mint);   ! Note 1
  [slp]         (mslp);   ! Note 1
  int with slp  (intslp); ! Note 1
  int           (vint);   ! Note 1
  slp           (vslp);   ! Note 1
  y1            (e12);
  y2            (e13);
  y3            (e14);
model g2:
  ! this is the model for group 2
  int by y1@1 y2@1 y3@1; 
  slp by y1@1; ! age 13
  slp by y2@2; ! age 14
  slp by y3@3; ! age 15
  [y1-y3@0];              ! Note 1
  [int]         (mint);   ! Note 1
  [slp]         (mslp);   ! Note 1
  int with slp  (intslp); ! Note 1
  int           (vint);   ! Note 1
  slp           (vslp);   ! Note 1
  y1            (e13);
  y2            (e14);
  y3            (e15);
model g3:
  ! this is the model for group 3
  int by y1@1 y2@1 y3@1; 
  slp by y1@2; ! age 14
  slp by y2@3; ! age 15
  slp by y3@4; ! age 16
  [y1-y3@0];              ! Note 1
  [int]         (mint);   ! Note 1
  [slp]         (mslp);   ! Note 1
  int with slp  (intslp); ! Note 1
  int           (vint);   ! Note 1
  slp           (vslp);   ! Note 1
  y1            (e14);
  y2            (e15);
  y3            (e16);
output: 
  standardized tech1;

! Note 1
!   Note that these constraints are repeated across all 
!   three groups. We may have been able to just include this
!   in the overall model and omitted them from each
!   of the group specific models.