title:
  Checked.
  Data from page 162 in EQS program.
  Input based on Appendix 6.1 page 162.
  Figure 6.1 page 77, first 3 groups only
  Output. 
    Table 6.2 (cohort sequential columns), page 79.
    NOTE. Correlation is standardized value of
      int with slope.
    Also see text at top of page 79.

    Also Table 6.3 (cohort sequential column), computed
    based on intercept and slope values, e.g.
      age 12: .310 + 0*.384 = .31
      age 13: .310 + 1*.384 = .694
      age 14: .310 + 2*.384 = 1.078
      age 15: .310 + 3*.384 = 1.462
      age 16: .310 + 4*.384 = 1.846
data:  
  file = ch6cs.dat;
  format = free;
  type = means covariance;
  ngroups = 3;
  nobservations = 248 250 231;
variable:  
  names = y1 y2 y3; 
analysis:  
  type = general mgroup meanstructure;          
model:
  int slp | y1@0 y2@1 y3@2;  ! group 1 model
  [int]         (mint);    ! Note 1
  [slp]         (mslp);    ! Note 1
  int with slp  (intslp);  ! Note 1
  int           (vint);    ! Note 1
  slp           (vslp);    ! Note 1
model g1: 
  int slp | y1@0 y2@1 y3@2; ! repeating group 1 model
  y1            (e12); ! error for age 12
  y2            (e13); ! error for age 13
  y3            (e14); ! error for age 14
model g2:
  int slp | y1@1 y2@2 y3@3; ! group 2 model
  y1            (e13); ! error for age 13
  y2            (e14); ! error for age 14
  y3            (e15); ! error for age 15
model g3:
  int slp | y1@2 y2@3 y3@4; ! group 3 model
  y1            (e14); ! error for age 14
  y2            (e15); ! error for age 15
  y3            (e16); ! error for age 16
output: 
  samp standardized tech1;

! Note 1: These parameters, by appearing in the overall
!   model with contraints, appear for all groups, 
!   constrained to be equal.