title: 
  curve of factors model for alcohol, tobacco, & marijuana
  manual method
  Data from table 5.1, page 64.
  Input from Appendix 5.3 page 160.
  Figure 5.3 page 71.
  Output on page 72
data:  
  file is ch5.dat;
  format is free;
  type is correlation means stdeviations;
  nobservations = 357;
variable:  
  names are y1-y12; 
  usevar =  y1-y12;
analysis:
  type = general meanstructure;          
model: 
  ! define time 1 factor 
  ftime1 by y1* (la) ! include * to indicate path is free
            y5@1
            y9  (lb);
  [y1 y5@0 y9];      ! estimate means except for y5, since
                     ! its path was held at 1

  ! define time 2 factor (same strategy as time 1 factor)
  ftime2 by y2*  (la)
            y6@1
            y10 (lb);
  [y2 y6@0 y10];

  ! define time 3 factor (same strategy as time 1 factor)
  ftime3 by y3* (la)
            y7@1
            y11 (lb);
  [y3 y7@0 y11];

  ! define time 4 factor (same strategy as time 1 factor)
  ftime4 by y4* (la)
            y8@1
            y12 (lb);
  [y4 y8@0 y12];
  
  ! define intercept and slope factors
  fint   by ftime1@1 ftime2@1 ftime3@1 ftime4@1;
  fslope by ftime1@0 ftime2@1 ftime3@2 ftime4@3;
  [fint fslope];

  ! allow alcohol indictators to correlate
  y1 with y2 y3 y4; y2 with y3 y4; y3 with y4;

  ! allow tobacco indictators to correlate
  y5 with y6 y7 y8; y6 with y7 y8; y7 with y8;

  ! allow marijuana indicators to correlate
  y9 with y10 y11 y12; y10 with y11 y12; y11 with y12;

output:  
  standardized;