Stat Computing > SPSS > Textbook Examples > Applied Regression Analysis, by Fox				Help the Stat Consulting Group by giving a gift
Loading

SPSS Textbook Examples
Applied Regression Analysis by John Fox
Chapter 15: Logit and probit models

page 440 Figure 15.1 Scatterplot of voting intention (1 represents yes, 0 represents no) by a scale of support for the status quo, for a sample of Chilean voters surveyed prior to the 1988 plebiscite. The points are jittered vertically to minimize overlapping. The solid straight line shows the linear least-squares fit; the solid curved line shows the fit of the logistic regression model; the broken line represents a lowess nonparametric regression.

GET FILE='D:\chile.sav'.
if intvote = 1 voting = 1.
if intvote = 2 voting = 0.

formats statquo (f2.0) voting (f3.1).

GGRAPH
  /GRAPHDATASET NAME="GraphDataset" VARIABLES= voting statquo 
  /GRAPHSPEC SOURCE=INLINE.
BEGIN GPL
SOURCE: s=userSource( id( "GraphDataset" ) )
DATA: voting=col( source(s), name( "voting" ) )
DATA: statquo=col( source(s), name( "statquo" ) )
GUIDE: axis( dim( 1 ), label( "Support for the Status Quo" ) )
GUIDE: axis( dim( 2 ), label( "Voting Intention" ) )
SCALE: linear( dim( 1 ) )
SCALE: linear( dim( 2 ), min(-0.5), max(1.5) )
ELEMENT: point.jitter( position( statquo * voting ) )
ELEMENT: line( position(smooth.linear ( statquo * voting ) ) )
ELEMENT: line( position(smooth.loess ( statquo * voting )), shape(shape.dash) ) 
END GPL.

page 452 Table 15.1 Deviances (-2 log likelihood) for several models fit to the women's labor force participation data. The following code is used for terms in the models: C constant; I husband's income; K presence of children; R region. The column labeled K + 1 gives the number of regressors in the model, including the constant.

GET FILE='D:\womenlf.sav'.

if workstat = 1 or workstat = 2 ws = 1.
if workstat = 0 ws = 0.
compute ik = husbinc*chilpres.
compute cons = 1.
compute rgn1 = 0.
if region = "Atlantic" rgn1 = 1.
compute rgn2 = 0.
if region = "BC" rgn2 = 1.
compute rgn3 = 0.
if region = "Ontario" rgn3 = 1.
compute rgn4 = 0.
if region = "Prairie" rgn4 = 1.
compute rgn5 = 0.
if region = "Quebec" rgn5 = 1.
execute.

model 0 with C:

NOTE: SPSS will not allow a logistic regression without a predictor. (i.e., just the constant). Therefore, you need to create a variable; here we created const. Then we entered our constant with the /noconst subcommand, which, in effect, gives us a model with just a constant.

LOGISTIC REGRESSION VAR=ws
 /METHOD=ENTER cons
 /noconst.
 

model 1 with C, I, K, R, I*K:

LOGISTIC REGRESSION VAR=ws
 /METHOD=ENTER husbinc chilpres rgn2 rgn3 rgn4 rgn5 ik.
 

model 2 with C, I, K, R:

LOGISTIC REGRESSION VAR=ws
 /METHOD=ENTER husbinc chilpres rgn2 rgn3 rgn4 rgn5.
 

model 3 with C, I, K, I*K:

LOGISTIC REGRESSION VAR=ws
 /METHOD=ENTER husbinc chilpres ik.
 

model 4 with C, I, R:

LOGISTIC REGRESSION VAR=ws
 /METHOD=ENTER husbinc rgn2 rgn3 rgn4 rgn5.
 

model 5: with C, K, R:

LOGISTIC REGRESSION VAR=ws
 /METHOD=ENTER chilpres rgn2 rgn3 rgn4 rgn5.
 

page 452 Table 15.2 Analysis of deviance table for terms in the logit model fit to the women's labor force participation data.

NOTE: To get the G**2 terms, subtract the deviances. 
Model 0 versus model 1: 356.16 - 316.54 = 39.62. 
Model 2 versus model 1: 317.30 - 316.54 = .76. 
Model 5 versus model 2: 322.44 - 317.30 = 5.14. 
Model 4 versus model 2: 347.86 - 317.30 = 30.56. 
Model 3 versus model 1: 319.12 - 316.54 = 2.58.

page 453 Figure 15.4 Fitted probability of young married women working outside the home, as a function of husband's income and presence of children. The solid line shows the logit model fit by maximum likelihood; the broken line shows the linear least-squares fit.

logistic regression var = ws 
 /method=enter chilpres husbinc 
 /save pre. 

regression 
 /dep = ws 
 /method=enter chilpres husbinc 
 /save pre. 

if chilpres = 1 pw1 = pre_1.
if chilpres = 0 pw2 = pre_1.
if chilpres = 1 lw1 = pre_2.
if chilpres = 0 lw2 = pre_2.
execute.

SORT CASES BY husbinc (A).

compute pw = pw1.
if missing(pw1) pw = pw2.
exe.

GGRAPH
  /GRAPHDATASET NAME="GraphDataset" VARIABLES= husbinc pw chilpres
  /GRAPHSPEC SOURCE=INLINE.
BEGIN GPL
SOURCE: s=userSource( id( "GraphDataset" ) )
DATA: pw=col( source(s), name( "pw" ) )
DATA: husbinc=col( source(s), name( "husbinc" ) )
DATA: chilpres=col( source(s), name( "chilpres" ), unit.category() )
GUIDE: axis( dim( 1 ), label( "Husband's Income" ) )
GUIDE: axis( dim( 2 ), label( "P(Working)" ), delta(.25) )
SCALE: linear( dim( 1 ), min(0), max(50) )
SCALE: linear( dim( 2 ), min(0), max(1) )
ELEMENT: line( position(smooth.linear ( husbinc * pw ) ), shape(chilpres) )
ELEMENT: line( position(smooth.loess ( husbinc * pw ) ), shape(chilpres) )
END GPL.

page 459 Figure 15.5 Partial-residual plot for husband's income in the women's labor force participation data. The broken line gives the logit fit; the solid line shows a lowess smooth of the plot. Note the four bands due to the four combinations of values of the dichotomous dependent variable and the dichotomous independent variable presence of children. Because husband's income is also discrete, many points are overplotted.

NOTE: Leverage, studentized residuals and dfbetas are being saved here so that this regression only has to be run once.

logistic regression var=ws 
 /method=enter chilpres husbinc 
 /save pre lev sre dfbeta. 

NOTE: pre_3 is generated here.

compute par = (ws-pre_3)/(pre_3*(1-pre_3)) - .0423*husbinc.
regression 
 /dep=par 
 /method=enter husbinc 
 /save pre. 

GGRAPH
  /GRAPHDATASET NAME="GraphDataset" VARIABLES= husbinc par pre_3
  /GRAPHSPEC SOURCE=INLINE.
BEGIN GPL
SOURCE: s=userSource( id( "GraphDataset" ) )
DATA: par=col( source(s), name( "par" ) )
DATA: husbinc=col( source(s), name( "husbinc" ) )
DATA: pre_3=col( source(s), name( "pre_3" ) )
GUIDE: axis( dim( 1 ), label( "Husband's Income $1000s" ) )
GUIDE: axis( dim( 2 ), label( "Partial Residual (Working)" ), start(0), delta(5) )
SCALE: linear( dim( 2 ), min(-5), max(5) )
ELEMENT: point( position( husbinc * par ) )
ELEMENT: line( position(smooth.linear ( husbinc * par )), shape(shape.dash) ) 
END GPL.

page 461 Figure 15.6 Plot of studentized residuals versus hat values for the logit model fit to the women's labor force participation data. Vertical lines are drawn at twice and three times the average hat value. Many points are overplotted.

logistic regression var=ws 
 /method=enter chilpres husbinc 
 /save lev sre dfbeta. 

compute pr = (ws - pre_3)/sqrt(pre_3*(1 - pre_3)).

formats lev_1 (f4.2) sre_1 (f2.0).
GGRAPH
  /GRAPHDATASET NAME="GraphDataset" VARIABLES= lev_1 sre_1
  /GRAPHSPEC SOURCE=INLINE.
BEGIN GPL
SOURCE: s=userSource( id( "GraphDataset" ) )
DATA: lev_1=col( source(s), name( "lev_1" ) )
DATA: sre_1=col( source(s), name( "sre_1" ) )
GUIDE: axis( dim( 1 ), label( "Hat-value" ) )
GUIDE: axis( dim( 2 ), label( "Studentized Residual" ), delta(2) )
GUIDE: form.line(position(*,-2), shape(shape.dash))
GUIDE: form.line(position(*,0), shape(shape.dash))
GUIDE: form.line(position(*,2), shape(shape.dash))
GUIDE: form.line(position(.0228), shape(shape.dash))
GUIDE: form.line(position(.034), shape(shape.dash))
SCALE: linear( dim( 2 ), min(-2), max(4) )
ELEMENT: point( position( lev_1 * sre_1 ) )
END GPL.

page 462 Figure 15.7 Index plots of approximate influence of each observation on the coefficients of husband's income and presence of children.

Panel (a)

GRAPH
  /SCATTERPLOT(BIVAR)=obs WITH dfb2_1.
   
  

Panel (b)

GRAPH
  /SCATTERPLOT(BIVAR)=obs WITH dfb1_1.
   

page 469 Figure 15.8 Fitted probabilities for the polytomous logit model, showing women's labor force participation as a function of husband's income and presence of children. The upper panel is for children present, the lower panel for children absent.

NOTE: The scaling of the x-axis is very different than in the text.

Panel (a)

GET FILE='D:\womenlf.sav'.
compute w0 = 0.
if workstat = 0 w0 = 1.
compute w1 = 0.
if workstat = 1 w1 = 1.
compute w2 = 0.
if workstat = 2 w2 = 1.
execute.

logistic regression var=w0 
 /method=enter husbinc chilpres 
 /save pre. 

USE ALL.
COMPUTE filter_$=(chilpres=1).
VARIABLE LABEL filter_$ 'chilpres=1 (FILTER)'.
VALUE LABELS filter_$  0 'Not Selected' 1 'Selected'.
FORMAT filter_$ (f1.0).
FILTER BY filter_$.
EXECUTE.

Children present / not working.

graph 
 /scatterplot(bivar) = husbinc with pre_1.
   

Children present / part-time.

logistic regression var=w1 
 /method=enter husbinc chilpres 
 /save pre. 

graph 
 /scatterplot(bivar) = husbinc with pre_2.
   

Children present / full-time.

logistic regression var=w2 
 /method=enter husbinc chilpres 
 /save pre.

graph 
 /scatterplot(bivar) = husbinc with pre_3.
   

Panel (b)

GET FILE='D:\womenlf.sav'.
compute w0 = 0.
if workstat = 0 w0 = 1.
compute w1 = 0.
if workstat = 1 w1 = 1.
compute w2 = 0.
if workstat = 2 w2 = 1.
execute.

logistic regression var=w0 
 /method=enter husbinc chilpres 
 /save pre. 

USE ALL.
COMPUTE filter_$=(chilpres=0).
VARIABLE LABEL filter_$ 'chilpres=1 (FILTER)'.
VALUE LABELS filter_$  0 'Not Selected' 1 'Selected'.
FORMAT filter_$ (f1.0).
FILTER BY filter_$.
EXECUTE.

Children absent / not working.

graph 
 /scatterplot(bivar) = husbinc with pre_1.
  

Children absent / part-time.

logistic regression var=w1 
 /method=enter husbinc chilpres 
 /save pre. 

graph 
 /scatterplot(bivar) = husbinc with pre_2.
  

Children absent / full-time.

logistic regression var=w2 
 /method=enter husbinc chilpres 
 /save pre. 

graph 
 /scatterplot(bivar) = husbinc with pre_3.
  

page 473 calculations in the middle of page 473 and the top of 474.

NOTE: The R-squared values given by SPSS are different from those in the text.

GET FILE='D:\womenlf.sav'.
compute nwk = 1.
if workstat = 0 nwk = 0.
execute.
logistic regression var=nwk 
 /method=enter husbinc chilpres. 

if workstat = 1 ptime = 0.
if workstat = 2 ptime = 1.
execute.
logistic regression var=ptime 
 /method=enter husbinc chilpres. 

page 480 Figure 15.13 Empirical logits for voter turnout by intensity of partisan preference and perceived closeness of the election, for the . 1956 U.S. presidential election.

data list list / logv1 logvc inten.
begin data.
.847  .9   0
.904 1.318 1
.981 2.084 2
end data.
execute.

formats logvc logv1 (f3.1).
value labels inten 0 "Weak" 1 "Medium" 2 "Strong".
variable level inten (ordinal).

GGRAPH
  /GRAPHDATASET NAME="GraphDataset" VARIABLES= inten logvc logv1
  /GRAPHSPEC SOURCE=INLINE.
BEGIN GPL
SOURCE: s=userSource( id( "GraphDataset" ) )
DATA: logvc=col( source(s), name( "logvc" ) )
DATA: logv1=col( source(s), name( "logv1" ) )
DATA: inten=col( source(s),  name("inten"), unit.category())
GUIDE: axis( dim( 1 ), label( "Intensity of Preference" ), start(0), delta(1) )
GUIDE: axis( dim( 2 ), label( "Turnout: log(voted/did not vote)" ), start(0), delta(.5) )
SCALE: cat(dim(1), include(".00", "1.00", "2.00"))
SCALE: linear( dim( 2 ), min(.5), max(2) )
ELEMENT: point( position( inten * logvc ) )
ELEMENT: line( position( inten * logvc ), shape(shape.dash) )
ELEMENT: point( position( inten * logv1 ) )
ELEMENT: line( position( inten * logv1 ) )
END GPL.

page 482 Table 15.4 Deviances for models fit to the American voter data. Terms: alpha - perceived closeness; beta - intensity of preference; gamma - closeness by preference interaction. The column labeled k + 1 gives the number of parameters in the model, including the constant mu.

data list list / perclose inten1 inten2 voted wv.
begin data.
0 0 0 1 91
0 0 0 0 39
0 1 0 1 121
0 1 0 0 49
0 0 1 1 64
0 0 1 0 24
1 0 0 1 214
1 0 0 0 87
1 1 0 1 284
1 1 0 0 76
1 0 1 1 201
1 0 1 0 25
end data.
execute.

weight by wv.

compute clspref1 = perclose*inten1.
compute clspref2 = perclose*inten2.
execute.

Model 1:

logistic regression var=voted 
 /method=enter perclose inten1 inten2 clspref1 clsp ref2.

Model 2:

logistic regression var=voted 
 /method=enter perclose inten1 inten2. 

Model 3:

logistic regression var=voted 
 /method=enter perclose clspref1 clspref2. 

Model 4:

logistic regression var=voted 
 /method=enter inten1 inten2 clspref1 clspref2. 

Model 5:

logistic regression var=voted 
 /method=enter perclose. 

Model 6:

logistic regression var=voted 
 /method=enter inten1 inten2. 

page 482 Table 15.5 Analysis of deviance table for the American voter data, showing alternative likelihood ratio tests for the main effects of perceived closeness of the election and intensity of partisan preference.

NOTE: To get the G**2 terms, subtract the deviances. 
Model 6 versus model 2: 1371.838 - 1363.552 = 8.286. 
Model 4 versus model 1: 1368.554 - 1356.434 = 12.120. 
Model 5 versus model 2: 1382.658 - 1363.552 = 19.106. 
Model 3 versus model 1: 1368.042 - 1356.434 = 11.608. 
Model 2 versus model 1: 1363.552 - 1356.434 = 7.118.

UCLA Researchers are invited to our Statistical Consulting Services
We recommend others to our list of Other Resources for Statistical Computing Help
These pages are Copyrighted (c) by UCLA Academic Technology Services